Fichier:COVID-19-Pandemie - TT (Trinidad und Tobago) - Tote (800px).svg
Taille de cet aperçu PNG pour ce fichier SVG : 800 × 450 pixels. Autres résolutions : 320 × 180 pixels | 640 × 360 pixels | 1 024 × 576 pixels | 1 280 × 720 pixels | 2 560 × 1 440 pixels.
Fichier d’origine (Fichier SVG, nominalement de 800 × 450 pixels, taille : 483 kio)
Ce fichier et sa description proviennent de Wikimedia Commons.
Description
| Description |
Deutsch: COVID-19-Pandemie - TT (Trinidad und Tobago) - Tote (800px) |
||
| Date | laufende Aktualisierungen | ||
| Source | Daten von der WHO - https://covid19.who.int/WHO-COVID-19-global-data.csv - durch Klicken auffindbar über https://covid19.who.int/table | ||
| Auteur | Summer ... hier! | ||
| SVG information |  Cette image vectorielle SVG a été créée avec Gnuplot  Cette représentation graphique SVG utilise du texte encapsulé qui peut être traduit facilement à l'aide d'un éditeur de texte. | ||
| Code source |
# input (Zeitformat und Separator definieren)
#
set timefmt "%Y-%m-%d"
set datafile separator ';'
# Variablen zeile_X_stat setzten
# (every ::0 steht für 'ab erster Zeile' und kann weggelassen werden)
stats $WHO_data every ::0 using 5 name "zeile_5_stat" nooutput
stats $WHO_data every ::0 using 6 name "zeile_6_stat" nooutput
stats $WHO_data every ::0 using 7 name "zeile_7_stat" nooutput
stats $WHO_data every ::0 using 8 name "zeile_8_stat" nooutput
# Start und Ende ermitteln und Label setzen (incl. Konsolenausgabe)
stats $WHO_data every ::0 u (strptime("%Y-%m-%d",strcol(1))) name "datum" nooutput
print ' -----Stats-(Timestamp)----'
print ' Start: ', strftime("%d. %B %Y",datum_min)
print ' Ende: ', strftime("%d. %B %Y",datum_max)
print ' --------------------------'
# label fuer Grafikueberschrtft oben links mit den ermittelten Werten setzen
set label 'Daten vom '.strftime("%d.%m.%y",datum_min).' bis '.strftime("%d.%m.%y",datum_max) at graph 0.03, graph 0.93
# als Workaround nehmen wir statt zweimal 'ylabel' hier zweimal 'label'
# (bei multiplot ist es schwierig fuer alle Plots ein ylabel mit gleichen seitl. Einzug zu finden)
set label "Tote (kumuliert)" at screen 0.017, 0.700 rotate by +90 center
set label "Tote" at screen 0.017, 0.300 rotate by +90 center
# output
#
# Name der SVG-Datei
set output 'COVID-19-Pandemie_-_TT_(Trinidad_und_Tobago)_-_Tote_(800px).svg'
unset key # keine Box fuer Legende
set border 3 # Rahmen unten (Bit 1) und links (+ Bit 2)
set xtics scale 0.7, 0.4 # Skalenstriche x-Achse etwas kleiner
set ytics scale 0.7, 0.4 # Skalenstriche y-Achse etwas kleiner
set ytics offset 0.4, 0.0 # Zahlen eine Idee nach rechts (mehr Abstand vom Label)
# 'Wasserzeichen' für commonsprüfung
set label 'TT' at screen 0.01, 0.02 textcolor rgb '#ffffff' font 'Arial,8'
# Gitterlinienen per Hand setzen
set style line 1 linetype rgb '#4f4f4f' linewidth 0.25 # Def. Major-grid
set style line 2 linetype rgb '#9f9f9f' linewidth 0.20 # def. Minor-grid
unset grid
set grid noxtics nomxtics # Keine Gitterlinen an der 1. X-Achse (Monate)
set grid x2tics nomx2tics # Gitterliniene an der 2. X-Achse (Kalenderwochen)
set grid ytics mytics # Gitterl. an der Y-Achse
set grid back # Gitter im Hintergrund
set grid linestyle 1, linestyle 2 # Setzen des linestyle fuer Major u. Minor
# X-Achsenbeschriftung:
# ueber x1 machen wir die Monatsbschriftung, ueber x2 die Kalenderwochenbeschriftung
#
# beide X-Achsen, also x1 und x2, als Zeitachse definieren
set xdata time
set x2data time
# Bereich (von - bis) der X-Achse definieren
# Beginnt am 1. Jan. 2020 und Edit heute plus 6 Tage
xrange_max=strftime("%Y-%m-%d", time(0) + (60*60*24*6))
# zuvor Berechnetes xrange_max setzten
set xrange ['2020-01-01': xrange_max]
set x2range ['2020-01-01': xrange_max]
# die Maker fuer Monat setzen wir per Hand. Als 'format' geben wir einen leeren String an damit
# kein Text generiert wird (fuer die untere Grafik setzen wir den Text spaeter)
set xtics format "" # Format auf Nichts damit gnuplot die folgenden Daten nicht aufloest
set xtics ( "2020-01-01" \
, "2020-02-01" \
, "2020-03-01" \
, "2020-04-01" \
, "2020-05-01" \
, "2020-06-01" \
, "2020-07-01" \
, "2020-08-01" \
, "2020-09-01" \
, "2020-10-01" \
, "2020-11-01" \
, "2020-12-01" \
, "2021-01-01" \
, "2021-02-01" \
, "2021-03-01" \
)
#
# Kalenderwochen-Striche
#
# fuer x2 (KW) ebendalls keine Beschriftung
set format x2 ''
# der 6. Jan. 2020 war ein Montag - da setzen wir den ersten Strich und die
# folgenden Striche alle 7 Tage (hier in 60 * 60 * 24 * 7 Sekunden)
set x2tics '2020-01-06', 60 * 60 * 24 * 7
set x2tics scale 0
set xtics nomirror
unset mxtics
# Format Y-Achse
set decimalsign locale "de_DE.utf8"
set format y "%'.0f"
set yrange [-5:*]
set ytics 25
set mytics 5
set ytics nomirror
# Zebramuster
set style rect fillcolor lt -1 fillstyle solid 0.06 noborder
do for [i=1:12:2] {
marker_start=sprintf("2020-%1.2d-01",i)
marker_stop =sprintf("2020-%1.2d-01",i+1)
set object rectangle from marker_start,graph 0 to marker_stop, graph 1
marker_start=sprintf("2021-%1.2d-01",i)
marker_stop =sprintf("2021-%1.2d-01",i+1)
set object rectangle from marker_start,graph 0 to marker_stop, graph 1
}
# Groesse und Schrift definieren
#
# Zur Variablen 'datum_max' siehe oben
my_svg_name=strftime("COVID_%d_%m_%Y_TT",datum_max)
set term svg size 800,450 font "Arial,16" name my_svg_name
###########################################################################################
set lmargin 10.0 # linker Rand fuer Beschriftung Y-Achse sollte nicht auf Auto stehen
set rmargin 1.0 # rechter Rand
set tmargin 1.0 # top margin
set bmargin 0.0 # bottom margin
set multiplot
# Ausgabe oberer Graph
set size 1.000, 0.550 # Groesse der Grafik
set origin 0.000, 0.450 # def. der linken unteren Ecke
unset xlabel
plot $WHO_data usi 1:8 axis x1y1 tit 'Infizierte' lt rgb '#700070' lw 1.75 with lines
# Ausgabe unterer Graph
set tmargin 0.4 # Wert von oben ueberschreiben damit Grafiken enger zusammen
unset bmargin # oben wurde bottommargin auf null gesetzt - jetzt wieder auto damit Platz fuer Skala
unset label #
set size 1.000, 0.450
set origin 0.000, 0.000
# Wenn das Datumsintervall so gross wird das die Labels zu eng gesetzt sind
# hier jeden zweiten Eintrag loeschen!
set xtics rotate by +30 center offset -1.5,-0.6
set xtics add ( " 2020" "2020-01-01" \
, "1. Feb." "2020-02-01" \
, "1. März" "2020-03-01" \
, "1. Apr." "2020-04-01" \
, "1. Mai" "2020-05-01" \
, "1. Jun." "2020-06-01" \
, "1. Jul." "2020-07-01" \
, "1. Aug." "2020-08-01" \
, "1. Sep." "2020-09-01" \
, "1. Okt." "2020-10-01" \
, "1. Nov." "2020-11-01" \
, "1. Dez." "2020-12-01" \
, " 2021" "2021-01-01" \
, "1. Feb." "2021-02-01" \
, "1. März" "2021-03-01" \
)
set xlabel "Datum (Monats- und KW-Skala)"
set yrange [-1:*]
set ytics 5
set mytics 5
# Ueber den Wert von lw kann man die Sichtbarkeit bei kl. Aufl. regulieren
plot $WHO_data usi 1:7 axis x1y1 tit '' lt rgb '#700070' lw 0.75 with impulses
unset multiplot
|
_-_Tote_(800px).svg?uselang=fr){kind=link}
Conditions d’utilisation
Moi, en tant que détenteur des droits d’auteur sur cette œuvre, je la publie sous la licence suivante :
 
|
Ce fichier est dans le domaine public selon les termes de la licence Creative Commons CC0 1.0 Universel. |
| La personne qui a associé une œuvre avec cet acte l’a placée dans le domaine public en renonçant mondialement à tous ses droits sur cette œuvre en vertu des lois relatives au droit d’auteur, ainsi qu’à tous les droits juridiques connexes et voisins qu’elle possédait sur l’œuvre, sans autre limite que celles imposées par la loi. Vous pouvez copier, modifier, distribuer et utiliser cette œuvre, y compris à des fins commerciales, sans qu’il soit nécessaire d’en demander la permission.
|
Historique du fichier
Cliquer sur une date et heure pour voir le fichier tel qu'il était à ce moment-là.
_-_Tote_(800px).svg&dir=prev){kind=link}
_-_Tote_(800px).svg&offset=20230713122617){kind=link}
_-_Tote_(800px).svg&offset=&limit=20){kind=link}
_-_Tote_(800px).svg&offset=&limit=50){kind=link}
_-_Tote_(800px).svg&offset=&limit=100){kind=link}
_-_Tote_(800px).svg&offset=&limit=250){kind=link}
_-_Tote_(800px).svg&offset=&limit=500){kind=link}
| Date et heure | Vignette | Dimensions | Utilisateur | Commentaire | |
|---|---|---|---|---|---|
| actuel | 26 décembre 2023 à 14:53 | | 800 × 450 (483 kio) | Summer ... hier! | update |
| 30 octobre 2023 à 17:41 |  | 800 × 450 (468 kio) | Summer ... hier! | update | |
| 6 octobre 2023 à 08:31 |  | 800 × 450 (461 kio) | Summer ... hier! | update | |
| 6 septembre 2023 à 19:51 |  | 800 × 450 (453 kio) | Summer ... hier! | update | |
| 24 août 2023 à 16:51 |  | 800 × 450 (449 kio) | Summer ... hier! | update | |
| 10 août 2023 à 10:51 |  | 800 × 450 (445 kio) | Summer ... hier! | update | |
| 3 août 2023 à 01:49 |  | 800 × 450 (443 kio) | Summer ... hier! | update | |
| 27 juillet 2023 à 12:49 |  | 800 × 450 (441 kio) | Summer ... hier! | update | |
| 26 juillet 2023 à 22:38 |  | 800 × 450 (441 kio) | Summer ... hier! | update | |
| 13 juillet 2023 à 13:26 |  | 800 × 450 (437 kio) | Summer ... hier! | update |
Utilisation du fichier
La page suivante utilise ce fichier :
Usage global du fichier
Les autres wikis suivants utilisent ce fichier :
- Utilisation sur de.wiki.x.io
_-_Tote_(800px).svg){kind=link}